⑴ 怎樣設置U盤文件按日期分類
任何一搏埋台電腦上都是始終按修改時間排列，如果手動更改的話，步驟如下；
1、首先將U盤插入電腦的USB介面；
2、打開計算機（或我的電腦）桌面上有新的U盤圖標；
3、點擊U盤圖標右鍵；
4、選擇排列依據項喚銀腔；
5、最後點擊修改日期即和衫可。
⑵ 怎樣設置U盤文件按日期分類
需要在U盤中先點擊右鍵選擇分組依據，按修改日期進行分組。然後再點擊右鍵選擇排序方式為修改日期就可以設置按照日期進行分類分組了。具體的設置方法如下：
1、將U盤插入到電腦的USB介面後在電腦桌面上雙擊我的電腦打伍汪帶開進入。
⑶ u盤里的照片怎樣分類打包
1、新建文件夾2、將圖片進亂虧行分類放在文件夾里3、將文件夾壓縮打包
1，你新建幾個文件夾，打開U盤盤符，在空白處右鍵、新建、文件夾，然後輸入名字就可以了。建立文件夾完畢。文件夾數目不限制。想重命名，就在文件夾上右鍵、重孫陪命名、輸入名字、回車就可以。
2，分類放在這些文件夾中。然後將圖片拖進分類好了的文件。
3，然後進行壓縮打包，然後選選住文件則陪蠢夾，滑鼠單擊右鍵進行壓縮打包。
4，然後就可以在硬碟分區中雙擊U盤,進入U盤文件目錄,看到文件分類。在文件目錄中的空白處點擊,彈出選項目錄。
⑷ 怎樣把U盤里的文件歸類存放
使用批處理文件
使用方法
1、新建txt或記事本，拷貝如下代碼，虛線框內所有文字。（代碼為網路搜索來的，忘了原創是誰了）
2、另存為任意名.bat（後綴為 .bat）。
3、將bat 文件放入U盤根目錄，雙擊運行即可。
--------------------------------------------------------------
@echo off
:: Code by JM 2006-12-17 CMD@XP
:: 出處：
mode con lines=28
title 文件歸類整理器-test
::===================================================================================
:: 目的：
::
:: 對當前目錄及其所有子目錄下的文件進行歸類。
::
:: 整理結果：
::
:: 在當前目錄及其子目錄下，以該文件夾里的文件類型名為文件夾名，在該文件
:: 所在目錄下建立形如 exe文件、rar文件 之類的文件夾，不同類型的文件移動到
:: 對應的文件夾下。
:: 如果以後增添了新文件，再次運行本腳本時，若該位置已經存在對應的文件夾，
:: 將把新添的文件保存在該文件夾下；若不存在對應的文件夾，將新建文件夾以保存
:: 該文件。
::
:: 已發現的問題：
:: ① move 命令無法移動 系統 或 隱藏 屬性的文件；
:: ② 不會整理無類型的文件。
::
:: 下一版將要實現的功能：
::
:: ① 對以當前目錄為起點，指定層深的子目錄進行整理；
:: ② 整理指定類型以外的文件。
::
:: 更新歷史：
::
:: 06.12.17
:: 修正了遇到無類型文件會自動退出的錯誤；更新了獲取相對路徑的代碼，效率有所提升；
::
:: 06.12.16
:: 增添了如下功能(V1.1)：
:: ① 能指定要處理的文件夾以及保存路徑；
:: ② 能指定要整理的類型；
:: ③ 跳過已經整理的文件；
::
:: 06.12.15
:: 在只能整理當前目錄下不同類型文件的基礎上，寫出了能對當前目錄及其所有子目錄下的
:: 不同類型文件進行操作的代碼，此為V1.0；
::===================================================================================
:note
cls
title 文件歸類整理器-說明
echo ╭────────╮
echo ╭─────────┤ 功 能 說 明 ├─────────╮
echo │ ╰────────╯ │
echo │ │
echo │ 本程序能對當前目錄及其所有子目錄下的文件進行 │
echo │ │
echo │ 歸類，具體效果如下： │
echo │ │
echo │ 在當前目錄及其子目錄下，以該文件夾里的文件 │
echo │ │
echo │ 類型名為文件夾名，在該文件所在目錄下建立形如 │
echo │ │
echo │ exe文件、rar文件 之類的文件夾，不同類型的文件移 │
echo │ │
echo │ 動到對應的文件夾下，以保持原來的文件夾結構不變。 │
echo │ │
echo │ 如果以後增添了新文件，再次運行本腳本時，若 │
echo │ │
echo │ 該位置已經存在對應的文件夾，將把新添的文件保存 │
echo │ │
echo │ 在該文件夾下；若不存在對應的文件夾，將新建文件 │
echo │ │
echo │ 夾以保存該文件。 │
echo │ │
echo ╰────────────────────────────╯
echo.
echo 按任意鍵進入下一步...
pause>nul
:config
cls
title 文件歸類整理器-參數設置
echo.
echo.
echo.
echo.
echo 請把要處理的文件夾拉到本窗口(直接回車將處理當前目錄)：
echo.
set "source_path=%cd%"
set /p source_path=
echo.
echo 請輸入保存位置絕對路徑(直接回車將保存在源文件夾下)：
set destination_path=
set /p destination_path=
echo.
echo 請輸入要處理的文件類型，多個類型以空格分隔
echo.
echo (如：rar exe；直接回車將處理所有類型)：
echo.
set type_included=
set /p type_included=
if exist "%source_path:"=%" (
set "source_path=%source_path:"=%\"
) else goto config
set "source_dir=%source_path:"=%"
rem ======= 計算源文件夾的層深 =======
set source_layers=0
set "source_dir_tmp=%source_dir%"
:get_source_layers
set "source_dir_tmp=%source_dir_tmp:*\=%"
set /a source_layers+=1
if not "%source_dir_tmp%"=="" goto get_source_layers
if defined destination_path set destination=yes
for /f "delims=" %%i in ('dir /a-d /b /s /oe "%source_path%"') do (
set "nx_name=%%~nxi"
call :build_dir "%%~xi" "%%~dpi"
set file_type=%%~xi
set "source_path=%%~dpi"
)
goto :eof
rem ======= 按文件類型創建文件夾 =======
:build_dir
set include=
for %%i in (%type_included%) do if /i "%1"==".%%i" set include=yes
if defined type_included if not defined include goto :eof
set types=%1
if %types%=="" goto :eof
set types=%types:~2,-1%
if not defined destination set destination_path=%2
set "destination_path=%destination_path:"=%"
if not "%destination_path:~-1%"=="\" set "destination_path=%destination_path%\"
rem ======= 獲取文件在源文件中的相對位置 =======
set source_sub_path=%2
set "source_sub_path=%source_sub_path:"=%"
set num=0
:get_source_sub_path
set "source_sub_path=%source_sub_path:*\=%"
set /a num+=1
if not %num% equ %source_layers% goto get_source_sub_path
rem ======= 獲取文件所在路徑的目錄名 =======
for /f "delims=" %%i in ("%destination_path:~0,-1%") do set "source_name=%%~nxi"
:: 通過對比文件類型名和文件所在路徑的目錄名來判斷哪些文件已經整理過
if "%source_name%"=="%types%文件" goto :eof
:: 判斷文件所在位置是否發生了變化
if %2=="%source_path%" (set chang_dir=) else set chang_dir=yes&set file_type=
:: 判斷要處理的文件是不是批處理文件自身
if "%destination_path%%nx_name%"=="%~f0" (set file_self=yes) else set file_self=
:: 判斷文件類型是否發生了變化
if /i "%1"=="%file_type%" (set same_type=yes) else set same_type=
if not defined destination set source_sub_path=
if not defined chang_dir (
if not defined file_self if not defined same_type md "%destination_path%%source_sub_path%%types%文件" 2>nul
) else (
if not defined file_self if not defined same_type md "%destination_path%%source_sub_path%%types%文件" 2>nul
)
if not defined file_self move /-y %2"%nx_name%" "%destination_path%%source_sub_path%%types%文件"
goto :eof
:: source_path：源文件夾路徑
:: source_layers：源文件夾的層深
:: destination_path：目的文件夾路徑
:: include：要排除的文件類型
:: destination：標志變數，用來判斷是否指定目的文件夾路徑
:: nx_name：源文件的文件名和後綴名組合
:: file_type：源文件的類型
:: source_sub_path：源文件相對於源文件夾的路徑
:: source_path_tmp：源文件夾路徑的臨時變數
:: source_name：源文件名
:: source_name_tmp：源文件名臨時變數
:: chang_dir：判斷文件夾是否發生變化的標志
:: same_type：判斷文件類型是否相同的變數
:: file_self：判斷是不是批處理文件自身的變數
:: included：要處理的文件類型
:: type_included：決定是否處理當前文件類型的標志
-------------------------------------------------------------------------